TF Trigs for Necros



Modi's set:

The following are various necros triggers and aliases that I have come
up with over my span of playing a necro...I am currently using tf 3.5a20
and these files will work with it, and while I wont guarantee them for
earlier versions, they should still work...
These use color often, so you may need to go in and edit things if you
can not support color. Also you will need to go through and edit all
of the various triggers that use specific undead names (like the horde
kill macro, etc) so that they use your own undead names....and dammit
dont use fred and barney ;)

Enjoy, and feel free to ask questions about these files if you have
problems...I will try and keep updating and fixing bugs, and hopefully
various people will keep posting them ;)

-Modi

E mail:  andrewm@lion.hsc.edu



--------------------------- new file ------------------------

; .muddir/mainrc

; these files require alias.tf

/set alias new
/load alias.tf

; load various files

/load .muddir/zspells
/load .muddir/znecro
/load .muddir/zheal

; this gags the noise on /reload and /party

/def -i -ag -F -hREDEF gagredef

/set partying 0

; easy to reset variables and trigs

/def reload = /load .muddir/mainrc
/def party = /load .muddir/zparty%;/set partying 1

; couple generic prot type spells

/alias sop !cast shield of protection at %{*-%{heal1}}%;\
        /if /test %{partying}==1%;/then \
                /send !p' casting sop at %{*-%{heal1}}%;/endif
/alias lrap !cast lesser physical invulnerability at %{*-%{heal1}}%;\
        /if /test %{partying}==1%;/then \
                /send !p' casting lrap at %{*-%{heal1}}%;/endif
/alias mi !cast mirror image at %{*-%{heal1}}%;\
        /if /test %{partying}==1%;/then \
                /send !p' casting mirrors at %{*-%{heal1}}%;/endif
/alias cad !cast aura detection at %{*-%{heal1}}%;\
        /if /test %{partying}==1%;/then \
                /send !p' casting aura detection at %{*-%{heal1}}%;/endif
/alias cgi !cast greater cold invulnerability at %{*-%{heal1}}%;\
        /if /test %{partying}==1%;/then \
                /send !p' casting gCold at %{*-%{heal1}}%;/endif

--------------------------- new file ------------------------

; .muddir/znecro

; you will need to redefine names in this to suit your undeads

/set preserve 1
/set undcombat 0
/set combining 0
/set combined 0
/set ud1 fred
/set ud2 barney
/set hauler barney
/set target none
/set lrapon 0
/set uhcon 0
/set killing 0
/set testbad 0
/set looting 0
/set tinning 0
/set eating 0

/alias tin_on /set tinning 1%;/echo Tinning on
/alias tin_off /set tinning 0%;/set eating 0%;/echo Tinning off
/alias eat_on /set eating 1%;/echo Eating on
/alias eat_off /set eating 0%;/echo Eating off
/alias loot_on /set looting 1%;/echo Looting on
/alias loot_off /set looting 0%;/echo Looting off
/alias preserve_on /set preserve 1%;/echo Preserving on
/alias preserve_off /set preserve 0%;/echo Preserving off
/alias haul_fred /set hauler fred
/alias haul_barney /set hauler barney

/def -i -p2 -ag -t'*undead arrives*' undeadgag
/def -i -p1 -abCyellow -t'*struggles out of its chains*' chainoff =\
        /if /test %{partying}==1%;/then \
                /send !p' undead deads to be chained%;/endif
/def -i -p1 -PCcyan -mregexp -F -t'(\(frozen\))'
/def -i -p1 -PCcyan -mregexp -F -t'(\(modi\'s undead\))'
/def -i -p1 -PCcyan -mregexp -F -t'(\[in chains\])'
/def -i -p1 -Ph -mregexp -F -t'(\(enchanted\))'

/def -i -p99 -mregexp -t'(resistin phys)' lrapoff =\
        /set lrapon 1%;/repeat -210 1 /lrapoff2
/def -i lrapoff2 = /set lrapon 0%;\
        /if /test %{partying}==1%;/then /send !p' LRAP is prob _OFF_%;\
        /else /echo -abCyellow >>>>> RAP OFF <<<<<%;/endif

/def -i -p9999 -F -mregexp -t'is DEAD, R.I.P.' fuckerdied =\
        /if /test %{preserve}==1%;/then pc%;/endif%;\
        /if /test %{looting}==1%;/then gf%;/endif%;\
        /if /test %{tinning}==1%;/then \
                /send !tin all%;/send !get all can%;/endif%;\
        /if /test %{eating}==1%;/then /send !eat can%;/endif%;\
        /echo -aCyellow UNDEAD ROUNDS: %{undcombat}%;/set undcombat 0

/def check = /echo -aB LRAP = %{lrapon} UNHC = %{uhcon}
/def -i -p2 -aB -mregexp -t'Undead is in vigorous combat' undfight = \
        /set undcombat=$[%{undcombat}+1]

;   Combining macro for zombie mud

/def -i combine = /set combining=1%;/do_combine
/def -i combineoff = /set combining=0%;/echo -ah COMBINED %{combined}%;\
        /set combined=0%;/send !cast stop

/def -i do_combine = /if /test %{combining}==1%;/then /send !csm%;/endif

/def -i -p99 -F -t"*ou utter the magic words 'hynttyyt*" combiner = \
        /set combined=$[%{combined}+1]%;\
        /if /test %{combining}==1%;/then /do_combine%;/endif %;\
        /echo -ah COMBINED %{combined}

/def -i -p99 -F -t'*There is no corpse 1 here.' = /if \
        /test %{combining}==1%;/then /combineoff%;/endif
/def -i -p99 -F -t'*There is no corpse 2 here.' = /if \
        /test %{combining}==1%;/then /combineoff%;/endif
/def -i -p99 -F -t'*You don\'t have enough spell points.' = /if \
        /test %{combining}==1%;/then /repeat -45 1 /do_combine%;/endif

/alias 1 scan %{heal1}
/alias 2 scan %{ud2}
/alias xx scan %{target}
/alias preserve /if /test %%{preserve}=1%;/then /set preserve 0%;\
        /else /set preserve 1%;/endif%;/echo Preserve: %{preserve}
/alias ud1 /set ud1 %{*}%;\
        /set heal1 %{*}%;/echo UD1: %{ud1} H1: %{heal1}
/alias ud2 /set ud2 %{*}%;/echo UD2 = %{ud2}
/alias chain /if /test %%{*}!=2%;/then !chain %{*-%{ud1}}%;\
        /else !chain %{ud2}%;/endif%;\
        /if /test %{partying}==1%;/then \
                /send !p' chaining undead %{*}%;/endif
/alias o /hoff %; lrap

; this checks for people i dont want to kill by accident when im sleepy

/def -i testforbad = /set testbad 0%;\
        /if /test %%{*}=~'fred'%;/then /set testbad 1%;\
        /elseif /test %%{*}=~'barney'%;/then /set testbad 1%;\
        /elseif /test %%{*}=~'undead'%;/then /set testbad 1%;\
        /elseif /test %%{*}=~'undead 1'%;/then /set testbad 1%;\
        /elseif /test %%{*}=~'undead 2'%;/then /set testbad 1%;\
        /elseif /test %%{*}=~'song'%;/then /set testbad 1%;\
        /elseif /test %%{*}=~'larssi'%;/then /set testbad 1%;\
        /elseif /test %%{*}=~'demon'%;/then /set testbad 1%;\
        /elseif /test %%{*}=~'diavlo'%;/then /set testbad 1%;/endif

/alias c1 /testforbad %{*}%;/if /test %{testbad}==0%;\
        /then /do_c1 %{*}%;/else /echo -aB BAD KILL%;/endif
/def -i do_c1 = /set target %{*}%;\
        /send !cast control at %{ud1} kill %{target}%;/send !scan %{ud1}

/alias c2 /testforbad %{*}%;/if /test %{testbad}==0%;\
        /then /do_c2 %{*}%;/else /echo -aB BAD KILL%;/endif
/def -i do_c2 = /set target %{*}%;\
        /send !cast control at %{ud2} kill %{target}%;/send !scan %{ud2}

/alias chk /testforbad %{*}%;/if /test %{testbad}==0%;\
        /then /do_chk %{*}%;/else /echo -aB BAD KILL%;/endif
/def -i do_chk = /set target %{*}%;\
        /send !cast control at %{ud1} kill %{target}%;/set killing 1%;\
        /send !scan %{heal1}%;\
        /echo -wzombie HORDE KILLING: %{target}

/def -p9999 -i -t'*Undead fred attacks*' fredkill =\
        /if /test %{killing}==1%;/then /dokill2%;/endif%;\
        /if /test %{partying}==1%;/then \
                /send !p' fred is attacking %{target}%;/endif
/def -p9999 -i -t'*Undead barney attacks*' barneykill =\
        /if /test %{killing}==1%;/then /dokill2%;/endif%;\
        /if /test %{partying}==1%;/then \
                /send !p' barney is attacking %{target}%;/endif
/def -i dokill2 = /send cast control at %{ud2} kill %{target}%;\
        /set killing 0

/alias swr /testforbad %{*}%;/if /test %{testbad}==0%;\
        /then /do_swr %{*}%;/else /echo -aB BAD KILL%;/endif
/def -i do_swr = /set target %{*}%;\
        /send !cast soul wrack at %{target}%;/send !exa %{target}


/def -i -p1 -aBCred -t'*Undead seems a bit confused*' uhcoff =\
        /set uhcon 0%;\
        /if /test %{partying}==1%;/then \
                /send !p' unh courage is _OFF_%;/endif
/def -i -aCyellow -t'*Undead seems more couraged*' uhcon =\
        /set uhcon 1%;\
        /if /test %{partying}==1%;/then \
                /send !p' unh courage is _ON_%;/endif

/alias fuse !cast soul fusion
/alias dc drop corpse %{*}
/alias us !use undead surgery at %{*-%{heal1}}%;\
        /set surgetarg %{*-%{heal1}}%;/set healing 0%;\
                /send !scan %{surgetarg}
/def -p2 -i -t'*You fail the skill*' =\
        /send !use undead surgery at %{surgetarg}
/alias iw !cast unholy courage at %{*-%{heal1}}
/alias z !drop all corpse %; gf %; !get all corpse
/alias cwho !who long Necromancer
/alias gf !loot %; give noeq to %{*-%{hauler}}
/alias as !get all %; !sell noeq
/alias targ /set target %{*}%;\
        /if /test %{partying}==1%;/then /send !p' target is now %{target}%;\
        /else /echo Target = %{target}%;/endif
/alias golem !cast reanimate flesh golem at corpse %{*}
/alias ww !who long Warlock
/alias pc !cast preservation at corpse %{*}
/alias ec cast enchant corpse at corpse %{*}
/alias cmu cast mark undead at %{*}
/alias cu cast cure undead at %{*}
/alias dac drop all corpse
/alias cew cast estimate weight at corpse %{*}
/alias cpd cast plane of dead
/alias csm cast soul merge at corpse %{1-1} and corpse %{2-2}
/alias eu examine undead %{*}
/alias sx sphit %{*-%{target}}
/def -i -p1 -au -t'*Spirit releases*' sprel
/def -i -p1 -au -t'*Spirit freezes*' spfrz
/def -i -p1 -au -t'*Spirit moves*' spmov

/alias sab !sell all from %{hauler}
/alias wf !cast control at %{ud1} wear all
/alias savetank !undrop %{ud1}%;!get all%;!save%;!give noeq to %{ud1}%;!wf

--------------------------- new file ------------------------

; .muddir/zheal
; Healing macro for zombie mud

/set healing 0
/set heal1 fred
/set healtype cure undead

/alias p /heal %{*-%{heal1}}
/alias ht_cu /ht cure undead
/alias ht_clw /ht cure light wounds
/alias ht_csw /ht cure serious wounds
/alias heal1 /set heal1 %{*}%;\
        /if /test %{partying}==1%;/then \
                /send !p' setting heal target to %{heal1}%;\
        /else /echo -aB Heal Target: %{heal1}%;/endif

/def -i heal = /set num=%{1-%{heal1}}%;/set healing=1%;/do_heal%;\
        /if /test %{partying}==1%;/then \
                /send !p' healing %{num}%;/endif%;\
        /echo -aB HEALING %{1-%{heal1}}

/def -i healoff = /set healing=0%;/send !cast stop
/def -i hoff = /healoff

/def -i ht = /set healtype %{*}%;\
        /if /test %{partying}==1%;/then \
                /send !p' setting heal type to %{healtype}%;\
        /else /echo -aB Heal Type set to %{healtype}%;/endif

/def -i do_heal = /if /test %{healing}==1%;\
        /then /send !cast %{healtype} at %{num}%;/endif

/def -i -p99  -F -t'*You are done with the chant.' healer = /if  \
        /test %{healing}==1%;/then /do_heal%;/endif

/def -i -p99 -F -t'*not need to be healed.' = /if \
        /test %{healing}==1%;/then /healoff%;/endif

/def -i -p99 -F -t'*You don\'t have enough spell points.' = /if \
        /test %{healing}==1%;/then /repeat -45 1 /do_heal%;/endif

/def -i -p99 -F -t'*Cast cure undead at what?' = \
        /if /test %{healing}==1%;/then /healoff%;/endif
/def -i -p99 -F -t'*Cast cure light wounds at what?' = \
        /if /test %{healing}==1%;/then /healoff%;/endif
/def -i -p99 -F -t'*Cast cure serious wounds at what?' = \
        /if /test %{healing}==1%;/then /healoff%;/endif

/def -i -p10000 -F -t'*is DEAD, R.I.P.' deadheal = \
        /set healing 0

--------------------------- new file ------------------------

; .muddir/spells

/def -i -p1 -P0BCblue -mregexp -t'(frtizvg)'
/def -i -p1 -P0BCblue -mregexp -t'(resistin phys)'
/def -i -p1 -P0BCblue -mregexp -t'(ja maisemat vaihtuu)'
/def -i -p1 -P0BCblue -mregexp -t'(prooot proot prot)'
/def -i -p1 -P0BCblue -mregexp -t'(hynttyyt yhteen)'
/def -i -p1 -P0BCblue -mregexp -t'(prgh burtsh)'
/def -i -p1 -P0BCblue -mregexp -t'(AI SAATANA)'
/def -i -p1 -P0BCblue -mregexp -t'(ne err fuei qopea)'
/def -i -p1 -P0BCblue -mregexp -t'(rautasahaa)'
/def -i -p1 -P0BCblue -mregexp -t'(pprrruuuuzgh stuffffffzzzz hdddiiiiiiiii)'
/def -i -p1 -P0BCblue -mregexp -t'(umbbaaaaah gurgladaaah tanguh!)'
/def -i -p1 -P0BCblue -mregexp -t'(umbbaaaaah gurgladaaah bowah!)'
/def -i -p1 -P0BCblue -mregexp -t'(kettinkia)'
/def -i -p1 -P0BCblue -mregexp -t'(OBEY MEEE)'
/def -i -p1 -P0BCblue -mregexp -t'(yum yum)'
/def -i -p1 -P0BCblue -mregexp -t'(healaappa pikkuparannus)'
/def -i -p1 -P0BCblue -mregexp -t'(healaappa persesuti)'
/def -i -p1 -P0BCblue -mregexp -t'("*" -> " ")'
/def -i -p1 -P0BCblue -mregexp -t'(corpore odimeugh)'
/def -i -p1 -P0BCblue -mregexp -t'(pipioux massux)'
/def -i -p1 -P0BCblue -mregexp -t'(hoyhen)'
/def -i -p1 -P0BCblue -mregexp -t'(ccarr reks)'
/def -i -p1 -P0BCblue -mregexp -t'(maaark yaar aaas)'
/def -i -p1 -P0BCblue -mregexp -t'(iikkki kii raakka kaa)'
/def -i -p1 -P0BCblue -mregexp -t'(ken on maassa kaunehin)'
/def -i -p1 -P0BCblue -mregexp -t'(kaltcorpore  brrrhhh)'
/def -i -p1 -P0BCblue -mregexp -t'(umbbaaaaah gurgladaaah guggiaah?)'
/def -i -p1 -P0BCblue -mregexp -t'raaaaaiisee thoo roonhs'
/def -i -p1 -P0BCblue -mregexp -t'SAATANAN KURJAT'
/def -i -p1 -P0BCblue -mregexp -t'lihaa lakoon'
/def -i -p1 -P0BCblue -mregexp -t'healaappa kohtuullista'

--------------------------- new file ------------------------

; .muddir/zparty
; primarily designed for partying with a warlock, tho will work w/ necro
; this file redefines some things, if you are using a tf version earlier
; than 3.5a20 i dunno what will happen. what is designed to happen is
; these trigs take over for old trigs.

/set reporting 1
/set looting 1
/set preserve 0
/set heal1 demon

/echo -aB LOOTING and REPORTING on
/echo -aB PRESERVE TURNED OFF
/echo -aB HEAL TARGET DEMON

/alias rep /set reporting %{*}

/def -i -p99 -aBCyellow -t'*Undead is not in a good shape*' udnigslite
/def -i -aBCyellow -F -t'*is not in a good shape*' nigslite = \
        /if /test %{reporting}==1%;/then !party say %{1} is nigs%;/endif

/def -i -p99 -aCred -t'*Undead is in bad shape*' udbslite
/def -i -aCred -F -t'*is in bad shape*' bslite = \
        /if /test %{reporting}==1%;/then !party say %{1} is in bs%;/endif

/def -i -p99 -aBCred -t'*Undead is in very bad shape*' udvbslite
/def -i -aBCred -F -t'*is in very bad shape*' vbslite = \
        /if /test %{reporting}==1%;/then !party say %{1} is in vbs%;/endif

/def -i -p99 -aBCbgred -t'*Undead is almost dead*' udadlite=\
        !party say Undead near death!
/def -i -aBCbgred -F -t'*is almost dead*' adlite = \
        /if /test %{reporting}==1%;/then !party say %{1} is AD%;/endif

/def -i -p1 -mregexp -aB -t"You follow your leader."
/def -i -p1 -mregexp -aB -t"You stop following" stopfollow =\
        !p' follow off
/def -i -p1 -mregexp -aB -t"You start following" startfollow =\
        !p' follow on
/def -i -p99 -mregexp -ag -t"Spell chance" gagspellchance
/def -i -p99 -mregexp -P0BCgreen -t"(mbr:  pf)" ppfon
/def -i -p99 -mregexp -P0BCyellow -t"(mbr: off)" ppfoff
/def -i -p99 -mregexp -P0B -t"(ldr:   -)" pldr
Back to main trigs page